怎么在UnityShader中利用速度映射圖實(shí)現(xiàn)運(yùn)動(dòng)模糊-創(chuàng)新互聯(lián)

本篇文章為大家展示了怎么在UnityShader中利用速度映射圖實(shí)現(xiàn)運(yùn)動(dòng)模糊，內(nèi)容簡(jiǎn)明扼要并且容易理解，絕對(duì)能使你眼前一亮，通過(guò)這篇文章的詳細(xì)介紹希望你能有所收獲。

成都創(chuàng)新互聯(lián)公司成立10余年來(lái)，這條路我們正越走越好，積累了技術(shù)與客戶資源，形成了良好的口碑。為客戶提供成都網(wǎng)站設(shè)計(jì)、做網(wǎng)站、網(wǎng)站策劃、網(wǎng)頁(yè)設(shè)計(jì)、域名與空間、網(wǎng)絡(luò)營(yíng)銷、VI設(shè)計(jì)、網(wǎng)站改版、漏洞修補(bǔ)等服務(wù)。網(wǎng)站是否美觀、功能強(qiáng)大、用戶體驗(yàn)好、性價(jià)比高、打開快等等，這些對(duì)于網(wǎng)站建設(shè)都非常重要，成都創(chuàng)新互聯(lián)公司通過(guò)對(duì)建站技術(shù)性的掌握、對(duì)創(chuàng)意設(shè)計(jì)的研究為客戶提供一站式互聯(lián)網(wǎng)解決方案，攜手廣大客戶，共同發(fā)展進(jìn)步。

原理：

像素的當(dāng)前幀的NDC坐標(biāo)（x,y值由uv映射而來(lái)，z值由深度值映射而來(lái)）——（使用_CurrentViewProjectionInverseMartix變換，并除以w分量）—— 像素的世界坐標(biāo) ——（使用_PreviousViewProjectionMatrix變換，并除以w分量）—— 像素的前一幀的NDC坐標(biāo) —— （當(dāng)前幀NDC-前一幀NDC）—— 速度

1.此代碼掛在攝像機(jī)上，使攝像機(jī)運(yùn)動(dòng)起來(lái)

using UnityEngine; 
using System.Collections; 
 
public class Translating : MonoBehaviour { 
 
 public float speed = 10.0f; 
 public Vector3 startPoint = Vector3.zero; 
 public Vector3 endPoint = Vector3.zero; 
 public Vector3 lookAt = Vector3.zero; 
 public bool pingpong = true; 
 
 private Vector3 curEndPoint = Vector3.zero; 
 
 // Use this for initialization 
 void Start () { 
 transform.position = startPoint; 
 curEndPoint = endPoint; 
 } 
 
 // Update is called once per frame 
 void Update () { 
 transform.position = Vector3.Slerp(transform.position, curEndPoint, Time.deltaTime * speed); 
 transform.LookAt(lookAt); 
 if (pingpong) { 
  if (Vector3.Distance(transform.position, curEndPoint) < 0.001f) { 
  curEndPoint = Vector3.Distance(curEndPoint, endPoint) < Vector3.Distance(curEndPoint, startPoint) ? startPoint : endPoint; 
  } 
 } 
 } 
}

2.此代碼掛在攝像機(jī)上

using System.Collections;
using System.Collections.Generic;
using UnityEngine;
 
public class MotionBlurWithDepthTexture : PostEffectsBase
{
 public Shader MotionBlurShader;
 private Material _motionBlurMaterial = null;
 
 public Material Material
 {
 get
 {
  _motionBlurMaterial = CheckShaderAndCreateMaterial(MotionBlurShader, _motionBlurMaterial);
  return _motionBlurMaterial;
 }
 }
 
 //定義運(yùn)動(dòng)模糊時(shí)模糊圖像使用的大小
 [Range(0.0f, 1.0f)] public float BlurSize = 0.5f;
 //定義一個(gè)Camera變量，獲取該腳本所在的攝像機(jī)組建，得到攝像機(jī)的視角和投影矩陣
 private Camera _myCamera;
 
 public Camera Camera
 {
 get
 {
  if (_myCamera == null)
  {
  _myCamera = GetComponent<Camera>();
  }
  return _myCamera;
 }
 }
 
 //定義一個(gè)變量保存 上一幀攝像機(jī)的視角 * 投影矩陣
 private Matrix4x4 _previousViewProjectionMatrix;
 
 //在OnEnable中設(shè)置攝像機(jī)的狀態(tài)，以獲得深度紋理
 void OnEnable()
 {
 Camera.depthTextureMode = DepthTextureMode.Depth;
 }
 
 void OnRenderImage(RenderTexture src, RenderTexture dest)
 {
 if (Material != null)
 {
  //將模糊大小傳給Shader
  Material.SetFloat("_BlurSize", BlurSize);
 
  //使用 視角 * 投影矩陣 對(duì)NDC（歸一化的設(shè)備坐標(biāo)）下的頂點(diǎn)坐標(biāo)進(jìn)行變換，得到該像素在世界空間下的位置
  //計(jì)算前一幀與當(dāng)前幀的位置差，生成該像素的速度
 
  //將 前一幀視角 * 投影矩陣 傳給Shader
  Material.SetMatrix("_PreviousViewProjectionMatrix", _previousViewProjectionMatrix);
  //計(jì)算 當(dāng)前幀視角 * 投影矩陣
  //Camera.projectionMatrix獲得當(dāng)前攝像機(jī)投影矩陣
  //Camera.worldToCameraMatrix獲得當(dāng)前攝像機(jī)視角矩陣
  Matrix4x4 currentViewProjectionMartix = Camera.projectionMatrix * Camera.worldToCameraMatrix;
  //計(jì)算 當(dāng)前幀視角 * 投影矩陣 的逆矩陣
  Matrix4x4 currentViewProjectionInverseMartix = currentViewProjectionMartix.inverse;
  //將當(dāng)前幀視角 * 投影矩陣 的逆矩陣 傳遞給Shader
  Material.SetMatrix("_CurrentViewProjectionInverseMartix", currentViewProjectionInverseMartix);
  //將 當(dāng)前幀視角 * 投影矩陣 保存為 前一幀視角 * 投影矩陣
  _previousViewProjectionMatrix = currentViewProjectionMartix;
 
  Graphics.Blit(src, dest, Material);
 }
 else
 {
  Graphics.Blit(src, dest);
 }
 }
}

3.此Shader賦值給代碼2

Shader "Unity Shaders Book/Chapter 13/MotionBlurWithDepthTexture"
{
 Properties
 {
 _MainTex ("Base (RGB)", 2D) = "white" {}
 //模糊圖像時(shí)使用的參數(shù)
 _BlurSize ("Blur Size", Float) = 1.0
 
 //這里并沒(méi)有聲明_PreviousViewProjectionMatrix和_CurrentViewProjectionInverseMartix
 //是因?yàn)閁nity并沒(méi)有提供矩陣類型的屬性，但仍然可以在CG代碼塊中定義這些矩陣，并從腳本中設(shè)置它們
 }
 SubShader
 {
 CGINCLUDE
 #include "UnityCG.cginc"
 
 sampler2D _MainTex;
 //使用_MainTex_TexelSize變量來(lái)對(duì)深度紋理的采樣坐標(biāo)進(jìn)行平臺(tái)化差異處理
 half4 _MainTex_TexelSize;
 //Unity傳遞來(lái)的深度紋理
 sampler2D _CameraDepthTexture;
 //聲明_PreviousViewProjectionMatrix和_CurrentViewProjectionInverseMartix
 float4x4 _PreviousViewProjectionMatrix;
 float4x4 _CurrentViewProjectionInverseMartix;
 half _BlurSize;
 
 //定義頂點(diǎn)著色器
 struct v2f {
 float4 pos : SV_POSITION;
 half2 uv : TEXCOORD0;
 //添加了用于深度紋理采樣的紋理坐標(biāo)變量
 half2 uv_depth : TEXCOORD1;
 };
 
 v2f vert(appdata_img v) {
 v2f o;
 o.pos = UnityObjectToClipPos(v.vertex);
 o.uv = v.texcoord;
 o.uv_depth = v.texcoord;
 
 //平臺(tái)差異化處理
 #if UNITY_UV_STARTS_AT_TOP
 if (_MainTex_TexelSize.y < 0) {
 o.uv_depth.y = 1 - o.uv_depth.y;
 }
 #endif
 
 return o;
 }
 
 //定義片元著色器
 fixed4 frag(v2f i) : SV_Target{
 //使用宏和紋理坐標(biāo)對(duì)深度紋理進(jìn)行采樣，得到深度值
 float d = SAMPLE_DEPTH_TEXTURE(_CameraDepthTexture, i.uv_depth);
 
 //構(gòu)建當(dāng)前像素的NDC坐標(biāo),xy坐標(biāo)由像素的紋理坐標(biāo)映射而來(lái)，z坐標(biāo)由深度值d映射而來(lái)
 float4 H = float4(i.uv.x * 2 - 1, i.uv.y * 2 - 1, d * 2 - 1, 1);
 //使用 當(dāng)前幀的視角 * 投影矩陣 的逆矩陣 對(duì)H進(jìn)行變換
 float4 D = mul(_CurrentViewProjectionInverseMartix, H);
 //把結(jié)果除以它的w分量，得到該像素世界空間下的坐標(biāo)
 float4 worldPos = D / D.w;
 
 //像素當(dāng)前幀NDC坐標(biāo)
 float4 currentPos = H;
 
 //使用 前一幀視角 * 投影矩陣 變換世界空間的的坐標(biāo)worldPos，并除以它的w分量，得到前一幀的NDC坐標(biāo)
 float4 previousPos = mul(_PreviousViewProjectionMatrix, worldPos);
 previousPos /= previousPos.w;
 
 //計(jì)算當(dāng)前幀與前一幀在屏幕空間下的位置差，得到該像素的速度
 float2 velocity = (currentPos.xy - previousPos.xy) / 2.0f;
 
 //使用速度值對(duì)鄰域像素進(jìn)行采樣，相加后取平均值得到一個(gè)模糊效果，使用_BlurSize控制采樣距離
 float2 uv = i.uv;
 float4 c = tex2D(_MainTex, uv);
 uv += velocity * _BlurSize;
 for (int it = 1; it < 3; it++, uv += velocity * _BlurSize) {
 float4 currentColor = tex2D(_MainTex, uv);
 c += currentColor;
 }
 c /= 3;
 
 return fixed4(c.rgb, 1.0);
 }
 ENDCG
 
 Pass
 {
 ZTest Always Cull Off ZWrite Off
 CGPROGRAM
 #pragma vertex vert
 #pragma fragment frag 
 ENDCG
 }
 }
 Fallback Off
}

上述內(nèi)容就是怎么在UnityShader中利用速度映射圖實(shí)現(xiàn)運(yùn)動(dòng)模糊，你們學(xué)到知識(shí)或技能了嗎？如果還想學(xué)到更多技能或者豐富自己的知識(shí)儲(chǔ)備，歡迎關(guān)注創(chuàng)新互聯(lián)成都網(wǎng)站設(shè)計(jì)公司行業(yè)資訊頻道。

另外有需要云服務(wù)器可以了解下創(chuàng)新互聯(lián)scvps.cn，海內(nèi)外云服務(wù)器15元起步，三天無(wú)理由+7*72小時(shí)售后在線，公司持有idc許可證，提供“云服務(wù)器、裸金屬服務(wù)器、高防服務(wù)器、香港服務(wù)器、美國(guó)服務(wù)器、虛擬主機(jī)、免備案服務(wù)器”等云主機(jī)租用服務(wù)以及企業(yè)上云的綜合解決方案，具有“安全穩(wěn)定、簡(jiǎn)單易用、服務(wù)可用性高、性價(jià)比高”等特點(diǎn)與優(yōu)勢(shì)，專為企業(yè)上云打造定制，能夠滿足用戶豐富、多元化的應(yīng)用場(chǎng)景需求。

網(wǎng)頁(yè)名稱：怎么在UnityShader中利用速度映射圖實(shí)現(xiàn)運(yùn)動(dòng)模糊-創(chuàng)新互聯(lián)
分享地址：http://muchs.cn/article2/dpcooc.html

成都網(wǎng)站建設(shè)公司_創(chuàng)新互聯(lián)，為您提供網(wǎng)站設(shè)計(jì)公司、移動(dòng)網(wǎng)站建設(shè)、定制網(wǎng)站、小程序開發(fā)、企業(yè)網(wǎng)站制作、域名注冊(cè)

聲明：本網(wǎng)站發(fā)布的內(nèi)容（圖片、視頻和文字）以用戶投稿、用戶轉(zhuǎn)載內(nèi)容為主，如果涉及侵權(quán)請(qǐng)盡快告知，我們將會(huì)在第一時(shí)間刪除。文章觀點(diǎn)不代表本網(wǎng)站立場(chǎng)，如需處理請(qǐng)聯(lián)系客服。電話：028-86922220；郵箱：631063699@qq.com。內(nèi)容未經(jīng)允許不得轉(zhuǎn)載，或轉(zhuǎn)載時(shí)需注明來(lái)源：創(chuàng)新互聯(lián)

猜你還喜歡下面的內(nèi)容