Jenkins中環(huán)境變量的過程有哪些-創(chuàng)新互聯(lián)

這篇文章將為大家詳細(xì)講解有關(guān)Jenkins中環(huán)境變量的過程有哪些，文章內(nèi)容質(zhì)量較高，因此小編分享給大家做個參考，希望大家閱讀完這篇文章后對相關(guān)知識有一定的了解。

專注于為中小企業(yè)提供成都網(wǎng)站設(shè)計、網(wǎng)站制作服務(wù),電腦端+手機(jī)端+微信端的三站合一,更高效的管理,為中小企業(yè)興國免費(fèi)做網(wǎng)站提供優(yōu)質(zhì)的服務(wù)。我們立足成都，凝聚了一批互聯(lián)網(wǎng)行業(yè)人才，有力地推動了上千多家企業(yè)的穩(wěn)健成長，幫助中小企業(yè)通過網(wǎng)站建設(shè)實現(xiàn)規(guī)模擴(kuò)充和轉(zhuǎn)變。

認(rèn)識 Jenkins 環(huán)境變量

Jenkins 環(huán)境變量就是通過env 關(guān)鍵字暴露出來的全局變量，可以在 Jenkins 文件的任何位置使用

其實和你使用的編程語言中的全局變量沒有實質(zhì)差別

查看 Jenkins 系統(tǒng)內(nèi)置環(huán)境變量

Jenkins 在系統(tǒng)內(nèi)置了很多環(huán)境變量方便我們快速使用，查看起來有兩種方式：

方式一：

直接在瀏覽器中訪問${YOUR_JENKINS_HOST}/env-vars.html 頁面就可以，比如http://localhost:8080/env-vars.html ，每個變量的用途寫的都很清楚

方式二

通過執(zhí)行printenv shell 命令來獲?。?/p>

pipeline {
  agent any

  stages {
    stage("Env Variables") {
      steps {
        sh "printenv"
      }
    }
  }
}

直接 Save - Build, 在終端 log 中你會看到相應(yīng)的環(huán)境變量，并且可以快速看到他們當(dāng)前的值

通常這兩種方式可以結(jié)合使用

讀取環(huán)境變量

上面我們說了env 是環(huán)境變量的關(guān)鍵字，但是讀取 Jenkins 內(nèi)置的這些環(huán)境變量，env 關(guān)鍵字是可有可無, 但不能沒了底褲，都要使用${xxx} 包圍起來。以BUILD_NUMBER 這個內(nèi)置環(huán)境變量舉例來說明就是這樣滴：

如果你在 Jenkins 文件中使用 shell 命令，使用這些內(nèi)置環(huán)境變量甚至可以不用{}， 來看一下：

pipeline {
  agent any

  stages {
    stage("Read Env Variables") {
      steps {
        echo "帶 env 的讀取方式：${env.BUILD_NUMBER}"
        echo "不帶 env 的讀取方式：${BUILD_NUMBER}"
        sh 'echo "shell 中讀取方式 $BUILD_NUMBER"'
      }
    }
  }
}

可以看到結(jié)果是一樣一樣滴，不管有幾種，記住第一種最穩(wěn)妥

內(nèi)置的環(huán)境變量雖好，但也不能完全滿足我們自定義的 pipeline 的執(zhí)行邏輯，所以我們也得知道如何定義以及使用自定義環(huán)境變量

自定義 Jenkins 環(huán)境變量

Jenkins pipeline 分聲明式（Declarative）和 腳本式（imperative）寫法，相應(yīng)的環(huán)境變量定義方式也略有不同，歸納起來有三種方式：

還是看個實際例子吧：

pipeline {
  agent any

  environment {
    FOO = "bar"
  }

  stages {
    stage("Custom Env Variables") {
      environment {
        NAME = "RGYB"
      }

      steps {
        echo "FOO = ${env.FOO}"
        echo "NAME = ${env.NAME}"

        script {
          env.SCRIPT_VARIABLE = "Thumb Up"
        }

        echo "SCRIPT_VARIABLE = ${env.SCRIPT_VARIABLE}"

        withEnv(["WITH_ENV_VAR=Come On"]) {
          echo "WITH_ENV_VAR = ${env.WITH_ENV_VAR}"
        }
      }
    }
  }
}

注意：withEnv(["WITH_ENV_VAR=Come On"]) {} 這里的 = 號兩側(cè)不能有空格，必須是key=value 的形式

一個完整的 pipeline 通常會有很多個 stage，環(huán)境變量在不同的 stage 有不同的值是很常見的，知道如何設(shè)置以及讀取環(huán)境變量后，我們還得知道如何重寫環(huán)境變量

重寫 Jenkins 環(huán)境變量

Jenkins 讓人相對困惑最多的地方就是重寫環(huán)境變量，但是只要記住下面這三條規(guī)則，就可以搞定一切了

• withEnv(["WITH_ENV_VAR=Come On"]) {} 內(nèi)置函數(shù)的這種寫法，可以重寫任意環(huán)境變量

• 定義在environment {} 的環(huán)境變量不能被腳本式定義的環(huán)境變量（env.key="value"）重寫

• 腳本式環(huán)境變量只能重寫腳本式環(huán)境變量

這三點是硬規(guī)則，沒涵蓋在這 3 點規(guī)則之內(nèi)的也就是被允許的了

三條規(guī)則就有點讓人頭大了，農(nóng)夫選豆種，舉例為證吧

pipeline {
  agent any

  environment {
    FOO = "你當(dāng)像鳥飛往你的山"
    NAME = "Tan"
  }

  stages {
    stage("Env Variables") {
      environment {
       	// 會重寫第 6 行 變量
        NAME = "RGYB" 
       	// 會重寫系統(tǒng)內(nèi)置的環(huán)境變量 BUILD_NUMBER
        BUILD_NUMBER = "10" 
      }

      steps {
       	// 應(yīng)該打印出 "FOO = 你當(dāng)像鳥飛往你的山"
        echo "FOO = ${env.FOO}" 
       	// 應(yīng)該打印出 "NAME = RGYB"
        echo "NAME = ${env.NAME}" 
       	// 應(yīng)該打印出 "BUILD_NUMBER = 10"
        echo "BUILD_NUMBER = ${env.BUILD_NUMBER}" 

        script {
         	// 腳本式創(chuàng)建一個環(huán)境變量
          env.SCRIPT_VARIABLE = "1" 
        }
      }
    }

    stage("Override Variables") {
      steps {
        script {
         	// 這里的 FOO 不會被重寫，違背 Rule No.2
          env.FOO = "Tara"
         	// SCRIPT_VARIABLE 變量會被重寫，符合 Rule No.3
          env.SCRIPT_VARIABLE = "2" 
        }

       	// FOO 在第 37 行重寫失敗，還會打印出 "FOO = 你當(dāng)像鳥飛往你的山"
        echo "FOO = ${env.FOO}" 
       	// 會打印出 "SCRIPT_VARIABLE = 2"
        echo "SCRIPT_VARIABLE = ${env.SCRIPT_VARIABLE}" 

       	// FOO 會被重寫，符合 Rule No.1
        withEnv(["FOO=Educated"]) { 
         	// 應(yīng)該打印 "FOO = Educated"
          echo "FOO = ${env.FOO}" 
        }

       	// 道理同上
        withEnv(["BUILD_NUMBER=15"]) {
         	// 應(yīng)該打印出 "BUILD_NUMBER = 15"
          echo "BUILD_NUMBER = ${env.BUILD_NUMBER}"
        }
      }
    }
  }
}

來驗證一下結(jié)果吧

看到這，基本的設(shè)置應(yīng)該就沒有什么問題了，相信你也發(fā)現(xiàn)了，Jenkins 設(shè)置環(huán)境變量和編程語言的那種設(shè)置環(huán)境變量還是略有不同的，后者可以將變量賦值為對象，但 Jenkins 就不行，因為在 Jenkins 文件中，所有設(shè)置的值都會被當(dāng)成 String， 難道沒辦法應(yīng)用 Boolean 值嗎？

Jenkins 中使用 Boolean 值

如果設(shè)置一個變量為false ，Jenkins 就會將其轉(zhuǎn)換為"false", 如果想使用 Boolean 來做條件判斷，必須要調(diào)用toBoolean() 方法做轉(zhuǎn)換

pipeline {
  agent any

  environment {
    IS_BOOLEAN = false
  }

  stages {
    stage("Env Variables") {
      steps {
        script {
         	// Hello 會被打印出來，因為非空字符串都會被認(rèn)為是 Boolean.True
          if (env.IS_BOOLEAN) {
            echo "Hello"
          }

         	// 真正的 Boolean 比較
          if (env.IS_BOOLEAN.toBoolean() == false) {
            echo "日拱一兵"
          }
         
         	// 真正的 Boolean 
          if (!env.IS_BOOLEAN.toBoolean()) {
            echo "RGYB"
          }
        }
      }
    }
  }
}

來看運(yùn)行結(jié)果：

如果你寫過 Pipeline，你一定會知道，寫 Pipeline 是離不開寫 shell 的，有些時候，需要將 shell 的執(zhí)行結(jié)果賦值給環(huán)境變量，Jenkins 也有方法支持

Shell 結(jié)果賦值給環(huán)境變量

實現(xiàn)這種方式很簡單，只需要記住一個格式：sh(script: 'cmd', returnStdout:true)

pipeline {
  agent any

  environment {
   	// 使用 trim() 去掉結(jié)果中的空格
    LS_RESULT = "${sh(script:'ls -lah', returnStdout: true).trim()}"
  }

  stages {
    stage("Env Variables") {
      steps {
        echo "LS_RESULT = ${env.LS_RESULT}"
      }
    }
  }
}

關(guān)于Jenkins中環(huán)境變量的過程有哪些就分享到這里了，希望以上內(nèi)容可以對大家有一定的幫助，可以學(xué)到更多知識。如果覺得文章不錯，可以把它分享出去讓更多的人看到。

分享標(biāo)題：Jenkins中環(huán)境變量的過程有哪些-創(chuàng)新互聯(lián)
瀏覽路徑：http://www.muchs.cn/article36/shosg.html

成都網(wǎng)站建設(shè)公司_創(chuàng)新互聯(lián)，為您提供小程序開發(fā)、App開發(fā)、虛擬主機(jī)、網(wǎng)站維護(hù)、全網(wǎng)營銷推廣、微信公眾號

廣告

聲明：本網(wǎng)站發(fā)布的內(nèi)容（圖片、視頻和文字）以用戶投稿、用戶轉(zhuǎn)載內(nèi)容為主，如果涉及侵權(quán)請盡快告知，我們將會在第一時間刪除。文章觀點不代表本網(wǎng)站立場，如需處理請聯(lián)系客服。電話：028-86922220；郵箱：631063699@qq.com。內(nèi)容未經(jīng)允許不得轉(zhuǎn)載，或轉(zhuǎn)載時需注明來源： 創(chuàng)新互聯(lián)