在PL/SQL中調(diào)用OracleERP請求（一）-提交單個請求-創(chuàng)新互聯(lián)

轉(zhuǎn)自：
/tupian/20230522/zhaisx-803274 />
PROCEDURE prc_do_import_request(prm_org     IN NUMBER,
                                  prm_appcode OUT NUMBER,
                                  prm_appmsg  OUT VARCHAR2) IS
    custom_exception EXCEPTION;
    success        BOOLEAN;
    v_request_id   NUMBER;
    v_phase        VARCHAR2(30);
    v_status       VARCHAR2(30);
    v_dev_phase    VARCHAR2(30);
    v_dev_status   VARCHAR2(30);
    v_message      VARCHAR2(1000);
    v_request_flag BOOLEAN;
    v_start_time   VARCHAR2(30);
  BEGIN
    prm_appcode := 0;
    --初始化設置
    fnd_global.apps_initialize(user_id      => global_user_id,--用戶ID
                               resp_id      => global_resp_id,          --責任ID
                               resp_appl_id => global_resp_appl_id);   --應用ID
    --設置打印參數(shù)
    success := fnd_request.set_print_options(printer => global_printer,
                                             style   => global_style,
                                             copies  => global_copies);
    IF NOT success THEN
      RAISE custom_exception;
    END IF;
    v_start_time := to_char(SYSDATE, 'DD-MON-YYYY HH24:MI:SS');
    --調(diào)用請求
    v_request_id := fnd_request.submit_request('INV',   --應用
                                               'INCOIN',                  --程序
                                               '',                              --程序說明
                                               v_start_time,               --開始時間
                                               FALSE,                        --是否作為子請求提交，該請求如果是被其它請求調(diào)用設為TRUE，否則為FALSE
                                               prm_org,                    --自定義參數(shù)1：組織機構(gòu)
                                               '1',                             --自定義參數(shù)2 ：
                                               '1',                             --自定義參數(shù)3：
                                               '1',                             --自定義參數(shù)4：
                                               '1',                             --自定義參數(shù)5：
                                               '1',                             --自定義參數(shù)6：
                                               '1',                             --自定義參數(shù)7：
                                               chr(0));                       --結(jié)束標識
    IF v_request_id = 0 THEN
      RAISE custom_exception;
    ELSE
      COMMIT;
    END IF;
    --等待
    v_request_flag := fnd_concurrent.wait_for_request(request_id => v_request_id,--返回的請求ID
                                                      INTERVAL   => 5,                                     --重復檢測時間差
                                                      max_wait   => 0,                                       --最長等待時間，0為一直等待
                                                      phase      => v_phase,
                                                      status     => v_status,
                                                      dev_phase  => v_dev_phase,
                                                      dev_status => v_dev_status,
                                                      message    => v_message);
    IF v_request_flag THEN
      IF v_dev_status = 'NORMAL' THEN
        NULL;
      ELSE
        RAISE custom_exception;
      END IF;
    ELSE
      RAISE custom_exception;
    END IF;
  EXCEPTION
    WHEN custom_exception THEN
      prm_appcode := -1;
      prm_appmsg  := '錯誤提示：導入ERP正式表出錯！' || SQLERRM;
    WHEN OTHERS THEN
      prm_appcode := -1;
      prm_appmsg  := '錯誤提示：導入ERP正式表出錯！' || SQLERRM;
  END prc_do_import_request;

當前題目：在PL/SQL中調(diào)用OracleERP請求（一）-提交單個請求-創(chuàng)新互聯(lián)
本文來源：http://muchs.cn/article22/eeijc.html

成都網(wǎng)站建設公司_創(chuàng)新互聯(lián)，為您提供企業(yè)建站、商城網(wǎng)站、外貿(mào)網(wǎng)站建設、小程序開發(fā)、網(wǎng)站制作、網(wǎng)站建設

廣告

聲明：本網(wǎng)站發(fā)布的內(nèi)容（圖片、視頻和文字）以用戶投稿、用戶轉(zhuǎn)載內(nèi)容為主，如果涉及侵權(quán)請盡快告知，我們將會在第一時間刪除。文章觀點不代表本網(wǎng)站立場，如需處理請聯(lián)系客服。電話：028-86922220；郵箱：631063699@qq.com。內(nèi)容未經(jīng)允許不得轉(zhuǎn)載，或轉(zhuǎn)載時需注明來源： 創(chuàng)新互聯(lián)