批處理bat如何實(shí)現(xiàn)目錄比較工具-創(chuàng)新互聯(lián)
小編給大家分享一下批處理bat如何實(shí)現(xiàn)目錄比較工具，相信大部分人都還不怎么了解，因此分享這篇文章給大家參考一下，希望大家閱讀完這篇文章后大有收獲，下面讓我們一起去了解一下吧！
更新日志：
v4:
1.增加了計(jì)算的進(jìn)度顯示；
2.找了新版的 md5sum.exe，沒(méi)有對(duì)動(dòng)態(tài)庫(kù)的依賴。
工具一：md5comv4.bat 接受兩個(gè)目錄參數(shù)，計(jì)算兩個(gè)目錄里每個(gè)文件的 md5 值，并給出報(bào)表文件 md5v4.txt，使用方法：
md5omv4.bat <目錄1> <目錄2>
根據(jù)這 md5comv4.bat 生成的報(bào)表文件 md5v4.txt，可以找到兩個(gè)目錄中
1：同名而且 md5 相同的文件；
2：同名但是 md5 不同的文件；
3：不同名但是 md5 相同的文件；
4：同一目錄中不同名但是 md5 相同的文件。
注意事項(xiàng)：
1：md5comv4.bat 不接受路徑帶有空格的目錄名，但是可以接受帶有空格的文件名；
2：md5 的計(jì)算由 md5sum.exe 完成；
3：md5comv4.bat 運(yùn)行時(shí)會(huì)產(chǎn)生大量臨時(shí)文件，這些文件由工具自動(dòng)維護(hù)，不必手工清理。
這個(gè)工具都是命令行方式、文本界面的，對(duì)于習(xí)慣使用圖形界面的朋友來(lái)說(shuō)，可能不方便，因此，不推薦習(xí)慣使用圖形界面的朋友使用。
代碼如下:
@echo off
setlocal enableextensions enabledelayedexpansion
rem 作者：rubble@126.com
rem 17:55 2009-4-14 版本：0.4
set dira=%~1
set dirb=%~2
if "%1" == "" (
echo 使用說(shuō)明：請(qǐng)?jiān)诿钚袇?shù)上指明兩個(gè)目錄，或在這里按提示輸入。
echo 命令行參數(shù)格式：批處理名 ^<目錄1^> ^<目錄2^>
echo.
set /p dira=請(qǐng)輸入第一個(gè)目錄的名字（可拖放并輸入回車）：
)
echo.
if "%2" == "" (
echo 使用說(shuō)明：請(qǐng)?jiān)诿钚袇?shù)上指明兩個(gè)目錄，或在這里按提示輸入。
echo 命令行參數(shù)格式：批處理名 ^<目錄1^> ^<目錄2^>
echo.
set /p dirb=請(qǐng)輸入第二個(gè)目錄的名字（可拖放并輸入回車）：
)
if "%dira%" == "" exit /b
if "%dirb%" == "" exit /b
for /F "delims=. tokens=1" %%A in ("%TIME%") do set startTime=%%A
for /F "delims=: tokens=1,2,3" %%A in ("%startTime%") do (
set startH=%%A
set startM=%%B
set startS=%%C
)
set TEMPDIR=TEMPMD5\
rd /Q /S %TEMPDIR% 1>NUL 2>NUL
md %TEMPDIR%
set mdfive=md5v4.txt
rem 已處理的文件數(shù)
set count=0
rem 文件夾 %dira% 和 %dirb% 里的文件總數(shù)
set total_count=0
rem 已處理的臨時(shí)文件數(shù)
set tmpf_count=0
rem 臨時(shí)文件總數(shù)，已知有 5 個(gè)了。其余的是 md5 值的個(gè)數(shù)
set tmpf_total_count=5
echo 第 1/2步，正在計(jì)算，請(qǐng)稍候……
echo 正在比較 %dira% 和 %dirb% 中的文件的 md5 值 > %mdfive%
set list_fn_md=%TEMPDIR%list_fn_md
set list_fn_nmd=%TEMPDIR%list_fn_nmd
set list_fn_oa=%TEMPDIR%list_fn_oa
set list_fn_ob=%TEMPDIR%list_fn_ob
set list_all_md=%TEMPDIR%list_all_md
call :COUNTFILES %dira%
call :COUNTFILES %dirb%
for /f "delims=" %%a in ('dir /b /a:-d "%dira%\*"') do (
set fn=%%~nxa
for /f "tokens=1 delims= " %%A in ('md5sum "%dira%\%%a"') do set mda=%%A
set /a count=!count!+1
call :PROGRESS !count! !total_count!
if "!mda:~0,1!" == "\" set mda=!mda:~1,1024!
rem 以 !mda! 為文件名，記錄 md5 為 !mda! 的文件
call :ADDMDFN "%TEMPDIR%!mda!" "%dira%\!fn!"
rem 把 md5 值記錄到文件里，保證不重復(fù)
call :ADDMDLIST !mda!
if exist "%dirb%\!fn!" (
for /f "tokens=1 delims= " %%A in ('md5sum "%dirb%\!fn!"') do set mdb=%%A
set /a count=!count!+1
call :ADDMDFN "%TEMPDIR%!mdb!" "%dirb%\!fn!"
call :PROGRESS !count! !total_count!
if "!mdb:~0,1!" == "\" set mdb=!mdb:~1,1024!
if "!mda!" == "!mdb!" (
rem 記錄文件名相同并且 md5 相同的文件
echo !mda! !mdb! !fn! >> "!list_fn_md!"
) else (
rem 記錄文件名相同但 md5 不相同的文件
echo !mda! !mdb! !fn! >> "!list_fn_nmd!"
call :ADDMDLIST !mdb!
)
) else (
rem 記錄只在 %dira% 中出現(xiàn)的文件
echo !mda! !fn! >> "!list_fn_oa!"
)
)
for /f "delims=" %%a in ('dir /b /a:-d "%dirb%\*"') do (
set fn=%%~nxa
if not exist "%dira%\!fn!" (
for /f "tokens=1 delims= " %%A in ('md5sum "%dirb%\%%a"') do set mdb=%%A
if "!mdb:~0,1!" == "\" set mdb=!mdb:~1,1024!
rem 記錄只在 %dirb% 中出現(xiàn)的文件
echo !mdb! !fn! >> "!list_fn_ob!"
rem 把 md5 值記錄到文件里，保證不重復(fù)
call :ADDMDLIST !mdb!
call :ADDMDFN "%TEMPDIR%!mdb!" "%dirb%\!fn!"
set /a count=!count!+1
call :PROGRESS !count! !total_count!
)
)
echo 第 2/2步，正在統(tǒng)計(jì)，請(qǐng)稍候……
echo 統(tǒng)計(jì)：>>%mdfive%
echo 左：%dira% >> %mdfive%
echo 右：%dirb% >> %mdfive%
if not exist "%list_fn_md%" set /a tmpf_total_count-=1
if not exist "%list_fn_nmd%" set /a tmpf_total_count-=1
if not exist "%list_fn_oa%" set /a tmpf_total_count-=1
if not exist "%list_fn_ob%" set /a tmpf_total_count-=1
if not exist "%list_all_md%" set /a tmpf_total_count-=1
echo 兩個(gè)目錄中都存在且 md5 相同的文件：>> %mdfive%
call :OUTPUTLIST "%list_fn_md%"
echo ===============================================================================================>> %mdfive%
echo 左：%dira% >> %mdfive%
echo 右：%dirb% >> %mdfive%
echo 兩個(gè)目錄中都存在但 md5 不相同的文件：>> %mdfive%
call :OUTPUTLIST "%list_fn_nmd%"
echo ===============================================================================================>> %mdfive%
echo 只在目錄 %dira% 中存在的文件：>> %mdfive%
call :OUTPUTLIST "%list_fn_oa%"
echo ===============================================================================================>> %mdfive%
echo 只在目錄 %dirb% 中存在的文件：>> %mdfive%
call :OUTPUTLIST "%list_fn_ob%"
echo ===============================================================================================>> %mdfive%
echo 以 md5 匯總的文件列表：>> %mdfive%
call :OUTPUTLIST_MD "%list_all_md%"
goto ALLDONE
rem 統(tǒng)計(jì)文件夾里的文件數(shù)目，放到全局變量 total_count 里
:COUNTFILES
if %1=="" goto :EOF
for /f %%a in ('dir /b /a:-d "%~1\*"') do (
set /a total_count=!total_count!+1
)
goto :EOF
rem 參數(shù) %1 必須加雙引號(hào)
:OUTPUTLIST
if %1 == "" goto :EOF
if not exist %1 goto :EOF
set tcnt=0
for /f "tokens=1* delims= " %%a in (%~1) do (
echo %%a %%b >> %mdfive%
set /a tcnt+=1
)
echo !tcnt! >> %mdfive%
set /a tmpf_count+=1
call :PROGRESS !tmpf_count! !tmpf_total_count!
goto :EOF
rem 參數(shù) %1 必須加雙引號(hào)
:OUTPUTLIST_MD
if %1 == "" goto :EOF
if not exist %1 goto :EOF
set /a tmpf_count+=1
call :PROGRESS !tmpf_count! !tmpf_total_count!
set md_count=0
for /f "tokens=1* delims= " %%a in (%~1) do (
echo %%a >> %mdfive%
set tcnt=0
for /f "tokens=1* delims= " %%A in (!TEMPDIR!%%a) do (
echo %%A %%B >> %mdfive%
set /a tcnt+=1
)
set /a tmpf_count+=1
call :PROGRESS !tmpf_count! !tmpf_total_count!
echo !tcnt! >> %mdfive%
set /a md_count+=1
echo. >> %mdfive%
)
echo %md_count% >> %mdfive%
goto :EOF
rem 函數(shù)：把 md5 值保存到一個(gè)名為 !list_all_md! 的文件里，
rem 并保證不保存重復(fù)的 md5 值
:ADDMDLIST
if %1 == "" goto :EOF
if exist "!list_all_md!" (
rem 這里的 delims 要么刪除，要么做成像下面這行的樣子，在等號(hào)后面加個(gè)空格
rem for /f "tokens=1 delims= " %%a in (!list_all_md!) do (
for /f "tokens=1 " %%a in (!list_all_md!) do (
if "%%a" == "%1" goto :EOF
)
)
echo %1 >> "!list_all_md!"
rem 記錄臨時(shí)文件總數(shù)
set /a tmpf_total_count+=1
goto :EOF
rem 函數(shù)：以 %1 為文件名，保存 %2
rem %1：在這個(gè)應(yīng)用里是 md5 值
rem %2：md5 值為 %1 的文件
:ADDMDFN
if %1 == "" goto :EOF
if %2 == "" goto :EOF
echo %2 >> %1
goto :EOF
:PROGRESS
set tips=
set backspace=
set /a percent=%1*100/%2
set /a char=%1%%7
set /a bnum=%percent%/10
set /a snum=10-%bnum%
for /L %%a in (1, 1, %bnum%) do set /p=▌<NUL
for /L %%a in (1, 1, %snum%) do set /p= <NUL
set /p=%1/%2 %percent%%% <NUL
set /p=!tips:~%char%,1!<NUL
if "%percent%" == "100" (
echo.
goto :EOF
)
set /p=%backspace%<NUL
goto :EOF
rem :PROGRESS
rem set tips=
rem set backspace=
rem set /a char=%1%%7
rem set /p=!tips:~%char%,1!<NUL
rem set /p=%backspace%<NUL
rem goto :EOF
:ALLDONE
rd /Q /S %TEMPDIR% 1>NUL 2>NUL
for /F "delims=. tokens=1" %%A in ("%TIME%") do set endTime=%%A
for /F "delims=: tokens=1,2,3" %%A in ("%endTime%") do (
set endH=%%A
set endM=%%B
set endS=%%C
)
if "%endM:~0,1%" == "0" set endM=%endM:~1,1%
if "%endS:~0,1%"=="0" set endS=%endS:~1,1%
for /F "delims=: tokens=1,2,3" %%A in ("%startTime%") do (
set startH=%%A
set startM=%%B
set startS=%%C
)
if "%startM:~0,1%"=="0" set startM=%startM:~1,1%
if "%startS:~0,1%"=="0" set startS=%startS:~1,1%
set /A totalTime=%endH%*3600+%endM%*60+%endS%-(%startH%*3600+%startM%*60+%startS%)
echo 共用時(shí) %totalTime% 秒。
echo 起始時(shí)間：%startH%:%startM%:%startS%>>%mdfive%
echo 結(jié)束時(shí)間：%endH%:%endM%:%endS%>>%mdfive%
echo 共用時(shí) %totalTime% 秒。>>%mdfive%
start %mdfive%
echo
endlocal
@echo on
以上是“批處理bat如何實(shí)現(xiàn)目錄比較工具”這篇文章的所有內(nèi)容，感謝各位的閱讀！相信大家都有了一定的了解，希望分享的內(nèi)容對(duì)大家有所幫助，如果還想學(xué)習(xí)更多知識(shí)，歡迎關(guān)注創(chuàng)新互聯(lián)行業(yè)資訊頻道！
標(biāo)題名稱：批處理bat如何實(shí)現(xiàn)目錄比較工具-創(chuàng)新互聯(lián)
分享地址：http://muchs.cn/article40/cshgho.html
成都網(wǎng)站建設(shè)公司_創(chuàng)新互聯(lián)，為您提供ChatGPT、云服務(wù)器、App開(kāi)發(fā)、域名注冊(cè)、外貿(mào)網(wǎng)站建設(shè)、關(guān)鍵詞優(yōu)化
聲明：本網(wǎng)站發(fā)布的內(nèi)容（圖片、視頻和文字）以用戶投稿、用戶轉(zhuǎn)載內(nèi)容為主，如果涉及侵權(quán)請(qǐng)盡快告知，我們將會(huì)在第一時(shí)間刪除。文章觀點(diǎn)不代表本網(wǎng)站立場(chǎng)，如需處理請(qǐng)聯(lián)系客服。電話：028-86922220；郵箱：631063699@qq.com。內(nèi)容未經(jīng)允許不得轉(zhuǎn)載，或轉(zhuǎn)載時(shí)需注明來(lái)源： 創(chuàng)新互聯(lián)
猜你還喜歡下面的內(nèi)容
- layui如何異步加載table表中某一列數(shù)據(jù)-創(chuàng)新互聯(lián)
- 什么是域名club-創(chuàng)新互聯(lián)
- 如何查看python庫(kù)是否安裝成功-創(chuàng)新互聯(lián)
- 省份簡(jiǎn)稱各省省會(huì)簡(jiǎn)稱？-創(chuàng)新互聯(lián)
- 詳解apache配置域名的坑-創(chuàng)新互聯(lián)
- python如何調(diào)用百度地圖api-創(chuàng)新互聯(lián)
- 如何使用PHP進(jìn)行手機(jī)APP開(kāi)發(fā)-創(chuàng)新互聯(lián)
- 煙臺(tái)網(wǎng)站排名利用TAG標(biāo)簽優(yōu)化聚合頁(yè)要害字的要容 2023-02-06
- 淺析網(wǎng)站tags標(biāo)簽優(yōu)化的重要性 2022-07-27
- META標(biāo)簽優(yōu)化如何做 2023-04-09
- HTML標(biāo)簽優(yōu)化的注意事項(xiàng)有哪些 2020-09-22
- 網(wǎng)站標(biāo)簽優(yōu)化之網(wǎng)頁(yè)標(biāo)簽優(yōu)化技巧 2014-03-25
- 網(wǎng)站結(jié)構(gòu)和標(biāo)簽優(yōu)化怎么做？ ?? 2014-08-12
- 那些不可忽視的title標(biāo)簽優(yōu)化方法？ 2022-06-21
- seo圖片alt標(biāo)簽優(yōu)化技巧 2022-09-28
- 網(wǎng)站權(quán)重的提升不僅僅依靠首頁(yè)流量還包括各個(gè)欄目頁(yè)標(biāo)簽優(yōu)化 2023-04-08
- seo培訓(xùn)：網(wǎng)站代碼和標(biāo)簽優(yōu)化 2020-07-23
- 關(guān)于網(wǎng)站標(biāo)簽優(yōu)化你了解多少 2021-09-02
- 搜索引擎推廣怎樣巧妙地運(yùn)用標(biāo)簽優(yōu)化網(wǎng)站？ 2023-04-24