怎么用vbs實(shí)現(xiàn)針對(duì)一個(gè)IP地址范圍運(yùn)行腳本-創(chuàng)新互聯(lián)

小編給大家分享一下怎么用vbs實(shí)現(xiàn)針對(duì)一個(gè)IP地址范圍運(yùn)行腳本，相信大部分人都還不怎么了解，因此分享這篇文章給大家參考一下，希望大家閱讀完這篇文章后大有收獲，下面讓我們一起去了解一下吧！

成都創(chuàng)新互聯(lián)公司堅(jiān)持“要么做到，要么別承諾”的工作理念，服務(wù)領(lǐng)域包括：成都做網(wǎng)站、成都網(wǎng)站設(shè)計(jì)、企業(yè)官網(wǎng)、英文網(wǎng)站、手機(jī)端網(wǎng)站、網(wǎng)站推廣等服務(wù)，滿足客戶于互聯(lián)網(wǎng)時(shí)代的志丹網(wǎng)站設(shè)計(jì)、移動(dòng)媒體設(shè)計(jì)的需求，幫助企業(yè)找到有效的互聯(lián)網(wǎng)解決方案。努力成為您成熟可靠的網(wǎng)絡(luò)建設(shè)合作伙伴！

問：
我想在一個(gè)子網(wǎng)中的所有計(jì)算機(jī)上運(yùn)行腳本。有沒有辦法不必將所有 IP 地址都硬編碼到腳本中就能完成這項(xiàng)任務(wù)呢？

-- RB

答：
根據(jù)您在電子郵件中的描述，看來您的設(shè)置類似于：您的子網(wǎng)的 IP 地址范圍為 192.168.1.1 到 192.168.1.254。您想創(chuàng)建一個(gè)腳本，可以先從第一個(gè) IP 地址開始，在相應(yīng)的計(jì)算機(jī)上運(yùn)行某個(gè)代碼，然后轉(zhuǎn)到第二個(gè)地址，運(yùn)行相同的代碼，按地址順序在每臺(tái)計(jì)算機(jī)上都運(yùn)行相同的腳本。此外，您想通過盡可能最少的代碼行就能辦到這一點(diǎn)，并且不必硬編碼好幾百個(gè) IP 地址。

那么，有辦法能做到嗎？當(dāng)然有，而且比您想象的還要簡(jiǎn)單。

首先，讓我們向您介紹如何某個(gè) IP 地址范圍進(jìn)行循環(huán)。這是一個(gè)示例代碼，所以只用于回顯每個(gè) IP 地址的名稱。在介紹了該腳本的工作原理后，我們將舉一個(gè)更實(shí)際的例子：



代碼如下:


On Error Resume Next 

intStartingAddress = 1 
intEndingAddress = 254 
strSubnet = "192.168.1." 

For i = intStartingAddress to intEndingAddress 
    strComputer = strSubnet & i 
    Wscript.Echo strComputer 
Next



不，真的，這就是整個(gè)腳本了。我們先指派了一些變量：將值“1”指派給 intStartingAddress；將值“254”指派給 intEndingAddress；并將值“192.168.1.”指派給 strSubnet。（注意“1”后面的英文句號(hào)）。正如您可能猜到的，這些值將作為建立 IP 地址的構(gòu)建塊。

指派了這些變量之后，我們創(chuàng)建了一個(gè) For-Next 循環(huán)，用以運(yùn)行 1 (intStartingAddress) 到 254 (intEndingAddress) 的變量。為何要循環(huán) 1 到 254 呢？原因很簡(jiǎn)單：那是您的 IP 范圍。如果 IP 范圍是 192.168.1.7 到 109.168.1.54，又該怎么辦呢？沒有問題：使用相同的循環(huán)，但要將intStartingAddress 的值改為“7”，并將 intEndingAddress 的值改為“54”。

在此循環(huán)中，我們將字符串值 192.168.1. 與循環(huán)變量 (i) 的當(dāng)前值相串聯(lián)。在首次運(yùn)行循環(huán)——當(dāng)“i”等于“1”時(shí)，我們將 192.168.1. 和 1 相結(jié)合。您猜怎么樣？我們得到了值 192.168.1.1，恰好是第一個(gè) IP 地址。最后一次運(yùn)行循環(huán)時(shí)，我們將把 192.168.1. 和 254 相結(jié)合，從而得到最后一個(gè) IP 地址的值——192.168.1.254。運(yùn)行該腳本，將得到：

192.168.1.1
192.168.1.2
192.168.1.3
192.168.1.4

非常簡(jiǎn)單吧？

當(dāng)然，您可能對(duì)于回顯一組 IP 地址不會(huì)多感興趣；您想運(yùn)行某種 WMI 代碼。好的：

On Error Resume Next

intStartingAddress = 1
intEndingAddress = 254
strSubnet = "192.168.1."

For i = intStartingAddress to intEndingAddress
    strComputer = strSubnet & i

    Set objWMIService = GetObject _
        ("winmgmts:\\" & strComputer & "\root\cimv2")
    Set colItems = objWMIService.ExecQuery _
        ("Select * From Win32_OperatingSystem")
    For Each objItem in ColItems
        Wscript.Echo strComputer & ": " & objItem.Caption
    Next

Next

正如您所看到的，我們?cè)俅伟?nbsp;strComputer 變量的值設(shè)為某個(gè) IP 地址。然后連接到該地址所表示的計(jì)算機(jī)上的 WMI 服務(wù)。這很容易辦到，因?yàn)?nbsp;WMI 既可以使用計(jì)算機(jī)名，也可以使用 IP 地址連接到計(jì)算機(jī)。

現(xiàn)在，我們要加入一項(xiàng)小技巧。您在電子郵件中提到，想要排除幾個(gè) IP 地址（可能代表路由器或其他東西）。好的。這里有一個(gè)經(jīng)過修改的腳本，其使用 Select Case 語(yǔ)句來排除某些計(jì)算機(jī)：

intEndingAddress = 254
strSubnet = "192.168.1."

For i = intStartingAddress to intEndingAddress
    Select Case i
        Case 10
        Case 50
        Case 100

        Case Else
            strComputer = strSubnet & i
            Set objWMIService = GetObject _
                ("winmgmts:\\" & strComputer & "\root\cimv2")
            Set colItems = objWMIService.ExecQuery _
                ("Select * From Win32_OperatingSystem")
            For Each objItem in ColItems
                Wscript.Echo strComputer & ": " & objItem.Caption
            Next

    End Select
Next

注意一下當(dāng)“i”值等于 10、50 或 100 時(shí)，所發(fā)生的變化。沒錯(cuò)：一點(diǎn)都沒變化。如果計(jì)算機(jī)的 IP 地址為 192.168.1.10、192.168.1.50 或 192.168.1.100，不會(huì)發(fā)生任何變化；不會(huì)運(yùn)行任何 WMI 代碼，腳本將照樣執(zhí)行循環(huán)。該 WMI 代碼將僅在擁有其他 IP 地址（上面三個(gè)地址除外）的計(jì)算機(jī)上執(zhí)行。這是一種用以在該腳本的 WMI 部分中排除特定 IP 地址的既簡(jiǎn)單又有效的辦法。


以上是“怎么用vbs實(shí)現(xiàn)針對(duì)一個(gè)IP地址范圍運(yùn)行腳本”這篇文章的所有內(nèi)容，感謝各位的閱讀！相信大家都有了一定的了解，希望分享的內(nèi)容對(duì)大家有所幫助，如果還想學(xué)習(xí)更多知識(shí)，歡迎關(guān)注創(chuàng)新互聯(lián)行業(yè)資訊頻道！

分享文章：怎么用vbs實(shí)現(xiàn)針對(duì)一個(gè)IP地址范圍運(yùn)行腳本-創(chuàng)新互聯(lián)
文章起源：http://muchs.cn/article18/csjddp.html

成都網(wǎng)站建設(shè)公司_創(chuàng)新互聯(lián)，為您提供云服務(wù)器、微信公眾號(hào)、網(wǎng)站策劃、網(wǎng)站內(nèi)鏈、動(dòng)態(tài)網(wǎng)站、做網(wǎng)站

廣告

聲明：本網(wǎng)站發(fā)布的內(nèi)容（圖片、視頻和文字）以用戶投稿、用戶轉(zhuǎn)載內(nèi)容為主，如果涉及侵權(quán)請(qǐng)盡快告知，我們將會(huì)在第一時(shí)間刪除。文章觀點(diǎn)不代表本網(wǎng)站立場(chǎng)，如需處理請(qǐng)聯(lián)系客服。電話：028-86922220；郵箱：631063699@qq.com。內(nèi)容未經(jīng)允許不得轉(zhuǎn)載，或轉(zhuǎn)載時(shí)需注明來源： 創(chuàng)新互聯(lián)

成都網(wǎng)站建設(shè)