VBS腳本中的字典、動(dòng)態(tài)數(shù)組、隊(duì)列和堆棧如何實(shí)現(xiàn)-創(chuàng)新互聯(lián)

這篇文章給大家分享的是有關(guān)VBS腳本中的字典、動(dòng)態(tài)數(shù)組、隊(duì)列和堆棧如何實(shí)現(xiàn)的內(nèi)容。小編覺得挺實(shí)用的，因此分享給大家做個(gè)參考，一起跟隨小編過來看看吧。

讓客戶滿意是我們工作的目標(biāo)，不斷超越客戶的期望值來自于我們對(duì)這個(gè)行業(yè)的熱愛。我們立志把好的技術(shù)通過有效、簡(jiǎn)單的方式提供給客戶，將通過不懈努力成為客戶在信息化領(lǐng)域值得信任、有價(jià)值的長(zhǎng)期合作伙伴，公司提供的服務(wù)項(xiàng)目有：申請(qǐng)域名、虛擬空間、營(yíng)銷軟件、網(wǎng)站建設(shè)、東莞網(wǎng)站維護(hù)、網(wǎng)站推廣。

1.編寫環(huán)境

今天突發(fā)奇想下載了個(gè)gVim來寫VBS腳本，我用的版本是7.4的

在寫腳本前，需要在gVim的安裝根目錄下，找到文件“_vimrc”，在里面添加下面三行：

set number
set softtabstop=4
set tabstop=4

意思分別是“顯示行號(hào)”、“按退格鍵一次刪掉4個(gè)空格”和“設(shè)定Tab長(zhǎng)度為4個(gè)字符”

這個(gè)設(shè)置類似于Linux系統(tǒng)下文件“.vimrc”的配置

1.字典：Scripting.Dictionary

VBS中的字典需要使用Scripting.Dictionary

腳本文件：a.vbs，包含字典的添加、刪除、判斷鍵是否存在、修改鍵、修改值、遍歷、統(tǒng)計(jì)鍵值對(duì)個(gè)數(shù)

Option Explicit

'建立字典
Dim Dict : Set Dict = CreateObject("Scripting.Dictionary")

'添加鍵值對(duì)
Dict.Add "Key1", "Item1"
Dict.Add "Key2", "Item2"
Dict.Add "Key3", "Item3"

'字典中鍵值對(duì)數(shù)量
WScript.Echo "字典中現(xiàn)有鍵值對(duì)數(shù)量: " & Dict.Count

WScript.Echo 

'檢查指定鍵是否存在
If Dict.Exists("Key1") Then
  WScript.Echo "Key1 存在!"
Else
  WScript.Echo "Key1 不存在!"
End If

If Dict.Exists("Keyn") Then
  WScript.Echo "Keyn 存在!"
Else
  WScript.Echo "Keyn 不存在!"
End If

WScript.Echo 

'遍歷字典
Sub TraverseDict
  Dim DictKeys, DictItems, Counter
  DictKeys = Dict.Keys
  DictItems = Dict.Items
  For Counter = 0 To Dict.Count - 1
    WScript.Echo _
      "鍵: " & DictKeys(Counter) & _
      "值: " & DictItems(Counter)
  Next
End Sub

TraverseDict

WScript.Echo 

'在一個(gè)鍵值對(duì)中，修改鍵或修改值
Dict.Key("Key2") = "Keyx"
Dict.Item("Key1") = "Itemx"
TraverseDict

WScript.Echo 

'刪除指定鍵
Dict.Remove("Key3")
TraverseDict

WScript.Echo 

'刪除全部鍵
Dict.RemoveAll
WScript.Echo "字典中現(xiàn)有鍵值對(duì)數(shù)量: " & Dict.Count

調(diào)用方法：通過雙擊a.bat調(diào)用，a.bat代碼如下：

cscript a.vbs
pause

運(yùn)行結(jié)果截圖：

2.動(dòng)態(tài)數(shù)組：System.Collections.ArrayList

VBS中的動(dòng)態(tài)數(shù)組需要使用System.Collections.ArrayList

腳本文件：b.vbs，包含動(dòng)態(tài)數(shù)組的添加元素、刪除元素、遍歷、統(tǒng)計(jì)元素個(gè)數(shù)、清空

Option Explicit

'建立動(dòng)態(tài)數(shù)組
Dim Arrl : Set Arrl = CreateObject("System.Collections.ArrayList")

'添加元素
Arrl.Add "Element3"
Arrl.Add "Element2"
Arrl.Add "Element1"

'查看動(dòng)態(tài)數(shù)組中的元素?cái)?shù)
WScript.Echo "動(dòng)態(tài)數(shù)組中現(xiàn)有元素?cái)?shù)量: " & Arrl.Count
WScript.Echo "動(dòng)態(tài)數(shù)組容量: " & Arrl.Capacity

WScript.Echo

'遍歷動(dòng)態(tài)數(shù)組
Sub TraverseArrl
  Dim Counter
  For Counter = 0 To Arrl.Count - 1
    WScript.Echo Arrl(Counter)
  Next
End Sub
TraverseArrl

WScript.Echo

'動(dòng)態(tài)數(shù)組排序
Arrl.Sort
TraverseArrl

WScript.Echo

'刪除指定元素
Arrl.Remove("Element1")
TraverseArrl

WScript.Echo

'清空全部元素
Arrl.Clear
WScript.Echo "動(dòng)態(tài)數(shù)組中現(xiàn)有元素?cái)?shù)量: " & Arrl.Count
WScript.Echo "動(dòng)態(tài)數(shù)組容量: " & Arrl.Capacity

調(diào)用方法：通過雙擊b.bat調(diào)用，b.bat代碼如下：

cscript b.vbs
pause

運(yùn)行結(jié)果截圖：

 

3.隊(duì)列：System.Collections.Queue

VBS中的隊(duì)列需要使用System.Collections.Queue

腳本文件：c.vbs，包含隊(duì)列的添加元素（入隊(duì)）、刪除元素（出隊(duì)）、遍歷、統(tǒng)計(jì)元素個(gè)數(shù)、清空

Option Explicit

'建立隊(duì)列
Dim Que : Set Que = CreateObject("System.Collections.Queue")

Que.EnQueue("Element1")
Que.EnQueue("Element2")
Que.EnQueue("Element3")

'查看隊(duì)列中的元素?cái)?shù)
WScript.Echo "隊(duì)列中的元素?cái)?shù): " & Que.Count

WScript.Echo

'遍歷隊(duì)列
Sub TraverseQue
  Dim ArrQue : ArrQue = Que.ToArray
  Dim Counter
  For Counter = 0 To UBound(ArrQue)
    WScript.Echo ArrQue(Counter)
  Next
End Sub
TraverseQue

WScript.Echo

'退出隊(duì)列
WScript.Echo Que.DeQueue
WScript.Echo "---"
TraverseQue
WScript.Echo

'清空隊(duì)列
Que.Clear
WScript.Echo "隊(duì)列中的元素?cái)?shù): " & Que.Count

調(diào)用方法：通過雙擊c.bat調(diào)用，c.bat代碼如下：

cscript c.vbs
pause

運(yùn)行結(jié)果截圖：

4.堆棧：System.Collections.Stack

VBS中的堆棧需要使用System.Collections.Stack

腳本文件：d.vbs，包含堆棧的添加元素（壓棧）、刪除元素（出棧）、遍歷、統(tǒng)計(jì)元素個(gè)數(shù)、清空

Option Explicit

'建立堆棧
Dim Stk : Set Stk = CreateObject("System.Collections.Stack")

Stk.Push "Element1"
Stk.Push "Element2"
Stk.Push "Element3"

'查看堆棧中的元素?cái)?shù)
WScript.Echo "堆棧中的元素?cái)?shù): " & Stk.Count

WScript.Echo

'遍歷堆棧
Sub TraverseStk
  Dim ArrStk : ArrStk = Stk.ToArray
  Dim Counter
  For Counter = 0 To UBound(ArrStk)
    WScript.Echo ArrStk(Counter)
  Next
End Sub
TraverseStk

WScript.Echo

'元素出棧
WScript.Echo Stk.Pop
WScript.Echo "---"
TraverseStk

WScript.Echo

'清空堆棧
Stk.Clear
WScript.Echo "堆棧中的元素?cái)?shù): " & Stk.Count

 調(diào)用方法：通過雙擊d.bat調(diào)用，d.bat代碼如下：

cscript d.vbs
pause

運(yùn)行結(jié)果截圖：

可以看出，遍歷隊(duì)列和堆棧時(shí)，遍歷順序時(shí)由出隊(duì)和出棧的順序決定的，而不是入隊(duì)和壓棧的順序

感謝各位的閱讀！關(guān)于“VBS腳本中的字典、動(dòng)態(tài)數(shù)組、隊(duì)列和堆棧如何實(shí)現(xiàn)”這篇文章就分享到這里了，希望以上內(nèi)容可以對(duì)大家有一定的幫助，讓大家可以學(xué)到更多知識(shí)，如果覺得文章不錯(cuò)，可以把它分享出去讓更多的人看到吧！

分享名稱：VBS腳本中的字典、動(dòng)態(tài)數(shù)組、隊(duì)列和堆棧如何實(shí)現(xiàn)-創(chuàng)新互聯(lián)
網(wǎng)站URL：http://muchs.cn/article22/csgejc.html

成都網(wǎng)站建設(shè)公司_創(chuàng)新互聯(lián)，為您提供用戶體驗(yàn)、虛擬主機(jī)、軟件開發(fā)、定制開發(fā)、全網(wǎng)營(yíng)銷推廣、品牌網(wǎng)站制作

廣告

聲明：本網(wǎng)站發(fā)布的內(nèi)容（圖片、視頻和文字）以用戶投稿、用戶轉(zhuǎn)載內(nèi)容為主，如果涉及侵權(quán)請(qǐng)盡快告知，我們將會(huì)在第一時(shí)間刪除。文章觀點(diǎn)不代表本網(wǎng)站立場(chǎng)，如需處理請(qǐng)聯(lián)系客服。電話：028-86922220；郵箱：631063699@qq.com。內(nèi)容未經(jīng)允許不得轉(zhuǎn)載，或轉(zhuǎn)載時(shí)需注明來源： 創(chuàng)新互聯(lián)